mirror of
https://github.com/OrcaSlicer/OrcaSlicer.git
synced 2026-09-16 13:32:44 +00:00
packerlschupfer
9321f24959
# Description
Add `--strict` for CI and scripted pipelines, and a structured
`warnings`
array in `result.json`.
## `--strict`
A NON_CRITICAL slicing warning is logged and the slice succeeds: return
code
`0`, G-code written. That suits interactive use, but a pipeline then
ships a
slice with a warning nobody saw. With `--strict`, such a warning fails
the run
with `CLI_SLICING_ERROR` before the G-code is exported. Without the
flag,
nothing changes.
In FFF the warning that reaches this path is "support needed but
disabled"
(`PrintObject::generate_support_material`). `--no-check` skips that
check, so
`--strict --no-check` is rejected with `CLI_INVALID_PARAMS`.
`--strict` is read before any work, so it doesn't depend on argument
order and
`result.json` reports it for early failures as well.
## `result.json`
Two new top-level fields:
- `warnings`: `[{"class", ...details}]`. One class is wired:
`slicing_warning_non_critical` with `plate_id` and `text`, recorded
whenever
such a warning fires, with or without `--strict`. The array also fills
on
runs that succeed, so `return_code` stays the verdict.
- `strict_mode`: whether `--strict` was on.
`record_exit_reson` writes `result.json` on Linux only, so both fields
exist
only there. The non-zero exit works on every platform.
## Tests
- `tests/fff_print/test_support_material.cpp` (all platforms): an
overhang
sliced with support off raises the NON_CRITICAL support-needed status,
and
the no-check flag suppresses it.
- `tests/cli/test_cli_strict.sh` (Linux only): runs `orca-slicer`
without
flags, with `--strict`, and with `--strict --no-check`, and checks the
shell
status and `result.json` of each. It runs the built binary, so it
carries the
`RequiresApp` label, which `scripts/run_unit_tests.sh` excludes because
the
unit-test job only receives `build/tests`. Run it with
`ctest --test-dir build/tests -C Release -L RequiresApp`.
- CI: `unit_tests.yml` now passes `Release` on Linux too.
`build_linux.sh`
configures Ninja Multi-Config, and without a config ctest drops the
labels of
plain `add_test()` tests, so this test ran as "Not Run" instead of being
excluded. The docs that assumed Linux was single-config are corrected
too.
Built and run locally on Linux (GCC 14) on current `main`: both tests
pass,
and the touched files compile clean under Clang with `-Werror`.
94 lines
3.9 KiB
CMake
94 lines
3.9 KiB
CMake
# Add individual tests as executables in separate directories at the bottom of this file
|
|
|
|
add_subdirectory(catch2)
|
|
|
|
# The top-level project defines _UNICODE globally, which makes Catch2's bundled
|
|
# main emit wmain instead of main. Test executables link with the default
|
|
# /SUBSYSTEM:CONSOLE entry point (mainCRTStartup, which calls main), so force
|
|
# Catch2 to emit main to keep the CRT entry point happy.
|
|
if(MSVC)
|
|
target_compile_definitions(Catch2WithMain PRIVATE DO_NOT_USE_WMAIN)
|
|
endif()
|
|
|
|
set(TEST_DATA_DIR ${CMAKE_CURRENT_SOURCE_DIR}/data)
|
|
file(TO_NATIVE_PATH "${TEST_DATA_DIR}" TEST_DATA_DIR)
|
|
|
|
# Shipped vendor profiles, so tests can exercise the real machine/filament gcode.
|
|
set(PROFILES_DIR ${CMAKE_SOURCE_DIR}/resources/profiles)
|
|
file(TO_NATIVE_PATH "${PROFILES_DIR}" PROFILES_DIR)
|
|
|
|
include(CTest)
|
|
include(Catch)
|
|
|
|
set(CATCH_EXTRA_ARGS "" CACHE STRING "Extra arguments for catch2 test suites.") # Unknown if this still works and/or should be replaced with something else.
|
|
|
|
add_library(test_common INTERFACE)
|
|
target_compile_definitions(test_common INTERFACE TEST_DATA_DIR=R"\(${TEST_DATA_DIR}\)" PROFILES_DIR=R"\(${PROFILES_DIR}\)" CATCH_CONFIG_FAST_COMPILE)
|
|
target_include_directories(test_common INTERFACE ${CMAKE_CURRENT_SOURCE_DIR})
|
|
|
|
if (APPLE)
|
|
target_link_libraries(test_common INTERFACE "-liconv -framework IOKit" "-framework CoreFoundation" -lc++)
|
|
endif()
|
|
|
|
# Copies runtime shared libraries next to each test executable. Handles both
|
|
# single-config generators (CMAKE_BUILD_TYPE set) and multi-config generators
|
|
# (Ninja Multi-Config, Visual Studio) where CMAKE_BUILD_TYPE is empty and DLLs
|
|
# must land in every per-config output directory. On Windows the loader finds
|
|
# DLLs in the executable's directory; the Linux branch below does the same for
|
|
# the deps-built FFmpeg libraries and adds an $ORIGIN rpath, since the ELF
|
|
# loader does not search the executable's directory and the CI unit-test runner
|
|
# only receives the tests artifact (no deps install).
|
|
function(orcaslicer_copy_test_dlls)
|
|
if (WIN32)
|
|
set(_configs ${CMAKE_CONFIGURATION_TYPES})
|
|
if (NOT _configs)
|
|
set(_configs "${CMAKE_BUILD_TYPE}")
|
|
endif()
|
|
foreach(_cfg IN LISTS _configs)
|
|
if (_cfg STREQUAL "Debug")
|
|
orcaslicer_copy_dlls(COPY_DLLS "Debug" "d" _unused_dlls)
|
|
else()
|
|
orcaslicer_copy_dlls(COPY_DLLS "${_cfg}" "" _unused_dlls)
|
|
endif()
|
|
endforeach()
|
|
elseif (UNIX AND NOT APPLE)
|
|
# Only test executables that link libslic3r_gui pull in the FFmpeg
|
|
# shared libraries (src/slic3r/CMakeLists.txt links PkgConfig::LIBAV
|
|
# into it). Copy them next to the executable and give it an $ORIGIN
|
|
# rpath so the loader finds them when the tests run on the CI unit-test
|
|
# runner, which only receives this build/tests tree.
|
|
get_target_property(_linked_libs ${_TEST_NAME}_tests LINK_LIBRARIES)
|
|
if (NOT "libslic3r_gui" IN_LIST _linked_libs)
|
|
return()
|
|
endif()
|
|
|
|
set_property(TARGET ${_TEST_NAME}_tests PROPERTY BUILD_RPATH "$ORIGIN")
|
|
set(_configs ${CMAKE_CONFIGURATION_TYPES})
|
|
if (NOT _configs)
|
|
set(_configs "${CMAKE_BUILD_TYPE}")
|
|
endif()
|
|
foreach(_cfg IN LISTS _configs)
|
|
orcaslicer_copy_sos(${_TEST_NAME}_tests "${_cfg}" "" _unused_sos)
|
|
endforeach()
|
|
endif()
|
|
endfunction()
|
|
|
|
# Register Catch2 tags as CTest labels so `ctest -L`/`-LE` can filter by tag.
|
|
function(orcaslicer_discover_tests TARGET)
|
|
catch_discover_tests(${TARGET} ADD_TAGS_AS_LABELS)
|
|
endfunction()
|
|
|
|
add_subdirectory(libnest2d)
|
|
add_subdirectory(libslic3r)
|
|
add_subdirectory(slic3rutils)
|
|
add_subdirectory(fff_print)
|
|
add_subdirectory(sla_print)
|
|
add_subdirectory(filament_group)
|
|
|
|
# End-to-end checks of the orca-slicer binary. Linux only: they read result.json, which the CLI
|
|
# writes on Linux only. src/ is added before tests/, so the target is known here.
|
|
if (UNIX AND NOT APPLE AND TARGET OrcaSlicer)
|
|
add_subdirectory(cli)
|
|
endif ()
|
|
|