mirror of
https://github.com/OrcaSlicer/OrcaSlicer.git
synced 2026-07-10 04:20:08 +00:00
781ecdc2c1
* ci: run unit tests on Windows and macOS The Unit Tests CI job only ran on Linux, so platform-specific bugs invisible to a Linux build could land undetected (e.g. the MSVC-only NfpPlacer crash fixed in #14267). The full non-[NotWorking] suite already builds and passes on every shipped arch, so this wires them into CI. A reusable unit_tests.yml, called once per built arch, downloads that arch's test artifact and runs ctest. Each build leg builds the test executables and uploads them; a single publish_test_results job on Linux aggregates the JUnit results into one check. Coverage: Linux x86_64 + aarch64, Windows x64 + arm64, macOS arm64. macOS x86_64 is deferred (cross-built on arm64, needs Rosetta). - build_release_vs.bat: "tests" token enables BUILD_TESTS - build_release_macos.sh: -T builds and runs tests; ORCA_TESTS_BUILD_ONLY builds them without running (used by CI) - scripts/run_unit_tests.sh: parameterized test dir and build config Addresses #11273. * ci: bump actions/checkout to v7 in reusable unit_tests workflow Match the actions/checkout v6->v7 bump (#14517) that upstream applied to the inline test job this reusable workflow replaces.
178 lines
5.3 KiB
Batchfile
178 lines
5.3 KiB
Batchfile
@REM OrcaSlicer build script for Windows with VS auto-detect
|
|
@echo off
|
|
set WP=%CD%
|
|
set _START_TIME=%TIME%
|
|
|
|
@REM Default target architecture to the host CPU arch; override by passing
|
|
@REM "x64" or "arm64" as an argument. PROCESSOR_ARCHITEW6432 covers a 32-bit
|
|
@REM shell running on a 64-bit OS, where PROCESSOR_ARCHITECTURE reads "x86".
|
|
set arch=x64
|
|
if /I "%PROCESSOR_ARCHITECTURE%"=="ARM64" set arch=ARM64
|
|
if /I "%PROCESSOR_ARCHITEW6432%"=="ARM64" set arch=ARM64
|
|
if /I "%1"=="arm64" set arch=ARM64
|
|
if /I "%2"=="arm64" set arch=ARM64
|
|
if /I "%1"=="x64" set arch=x64
|
|
if /I "%2"=="x64" set arch=x64
|
|
|
|
@REM Check for Ninja Multi-Config option (-x)
|
|
set USE_NINJA=0
|
|
for %%a in (%*) do (
|
|
if "%%a"=="-x" set USE_NINJA=1
|
|
)
|
|
|
|
@REM Check for unit-tests option ("tests")
|
|
set BUILD_TESTS=OFF
|
|
for %%a in (%*) do (
|
|
if /I "%%a"=="tests" set BUILD_TESTS=ON
|
|
)
|
|
|
|
if "%USE_NINJA%"=="1" (
|
|
echo Using Ninja Multi-Config generator
|
|
set CMAKE_GENERATOR="Ninja Multi-Config"
|
|
set VS_VERSION=Ninja
|
|
goto :generator_ready
|
|
)
|
|
|
|
@REM Detect Visual Studio version using msbuild
|
|
echo Detecting Visual Studio version using msbuild...
|
|
|
|
@REM Try to get MSBuild version - the output format varies by VS version
|
|
set VS_MAJOR=
|
|
for /f "tokens=*" %%i in ('msbuild -version 2^>^&1 ^| findstr /r "^[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*"') do (
|
|
for /f "tokens=1 delims=." %%a in ("%%i") do set VS_MAJOR=%%a
|
|
set MSBUILD_OUTPUT=%%i
|
|
goto :version_found
|
|
)
|
|
|
|
@REM Alternative method for newer MSBuild versions
|
|
if "%VS_MAJOR%"=="" (
|
|
for /f "tokens=*" %%i in ('msbuild -version 2^>^&1 ^| findstr /r "[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*"') do (
|
|
for /f "tokens=1 delims=." %%a in ("%%i") do set VS_MAJOR=%%a
|
|
set MSBUILD_OUTPUT=%%i
|
|
goto :version_found
|
|
)
|
|
)
|
|
|
|
:version_found
|
|
echo MSBuild version detected: %MSBUILD_OUTPUT%
|
|
echo Major version: %VS_MAJOR%
|
|
|
|
if "%VS_MAJOR%"=="" (
|
|
echo Error: Could not determine Visual Studio version from msbuild
|
|
echo Please ensure Visual Studio and MSBuild are properly installed
|
|
exit /b 1
|
|
)
|
|
|
|
if "%VS_MAJOR%"=="16" (
|
|
set VS_VERSION=2019
|
|
set CMAKE_GENERATOR="Visual Studio 16 2019"
|
|
) else if "%VS_MAJOR%"=="17" (
|
|
set VS_VERSION=2022
|
|
set CMAKE_GENERATOR="Visual Studio 17 2022"
|
|
) else if "%VS_MAJOR%"=="18" (
|
|
set VS_VERSION=2026
|
|
set CMAKE_GENERATOR="Visual Studio 18 2026"
|
|
) else (
|
|
echo Error: Unsupported Visual Studio version: %VS_MAJOR%
|
|
echo Supported versions: VS2019 (16.x^), VS2022 (17.x^), VS2026 (18.x^)
|
|
exit /b 1
|
|
)
|
|
|
|
echo Detected Visual Studio %VS_VERSION% (version %VS_MAJOR%)
|
|
echo Using CMake generator: %CMAKE_GENERATOR%
|
|
|
|
:generator_ready
|
|
|
|
@REM Pack deps
|
|
if "%1"=="pack" (
|
|
setlocal ENABLEDELAYEDEXPANSION
|
|
cd %WP%/deps/build
|
|
if "%arch%"=="ARM64" cd %WP%/deps/build-arm64
|
|
for /f "tokens=2-4 delims=/ " %%a in ('date /t') do set build_date=%%c%%b%%a
|
|
echo packing deps: OrcaSlicer_dep_win-!arch!_!build_date!_vs!VS_VERSION!.zip
|
|
|
|
%WP%/tools/7z.exe a OrcaSlicer_dep_win-!arch!_!build_date!_vs!VS_VERSION!.zip OrcaSlicer_dep
|
|
goto :done
|
|
)
|
|
|
|
set debug=OFF
|
|
set debuginfo=OFF
|
|
if "%1"=="debug" set debug=ON
|
|
if "%2"=="debug" set debug=ON
|
|
if "%1"=="debuginfo" set debuginfo=ON
|
|
if "%2"=="debuginfo" set debuginfo=ON
|
|
if "%debug%"=="ON" (
|
|
set build_type=Debug
|
|
set build_dir=build-dbg
|
|
) else (
|
|
if "%debuginfo%"=="ON" (
|
|
set build_type=RelWithDebInfo
|
|
set build_dir=build-dbginfo
|
|
) else (
|
|
set build_type=Release
|
|
set build_dir=build
|
|
)
|
|
)
|
|
if "%arch%"=="ARM64" set build_dir=%build_dir%-arm64
|
|
echo build type set to %build_type%, arch=%arch%
|
|
|
|
setlocal DISABLEDELAYEDEXPANSION
|
|
cd deps
|
|
mkdir %build_dir%
|
|
cd %build_dir%
|
|
set "SIG_FLAG="
|
|
if defined ORCA_UPDATER_SIG_KEY set "SIG_FLAG=-DORCA_UPDATER_SIG_KEY=%ORCA_UPDATER_SIG_KEY%"
|
|
|
|
if "%1"=="slicer" (
|
|
GOTO :slicer
|
|
)
|
|
echo "building deps.."
|
|
|
|
echo on
|
|
REM Set minimum CMake policy to avoid <3.5 errors
|
|
set CMAKE_POLICY_VERSION_MINIMUM=3.5
|
|
if "%USE_NINJA%"=="1" (
|
|
cmake ../ -G %CMAKE_GENERATOR% -DCMAKE_BUILD_TYPE=%build_type%
|
|
cmake --build . --config %build_type% --target deps
|
|
) else (
|
|
cmake ../ -G %CMAKE_GENERATOR% -A %arch% -DCMAKE_BUILD_TYPE=%build_type%
|
|
cmake --build . --config %build_type% --target deps -- -m
|
|
)
|
|
@echo off
|
|
|
|
if "%1"=="deps" goto :done
|
|
|
|
:slicer
|
|
echo "building Orca Slicer..."
|
|
cd %WP%
|
|
mkdir %build_dir%
|
|
cd %build_dir%
|
|
|
|
echo on
|
|
set CMAKE_POLICY_VERSION_MINIMUM=3.5
|
|
if "%USE_NINJA%"=="1" (
|
|
cmake .. -G %CMAKE_GENERATOR% -DORCA_TOOLS=ON %SIG_FLAG% -DBUILD_TESTS=%BUILD_TESTS% -DCMAKE_BUILD_TYPE=%build_type%
|
|
cmake --build . --config %build_type% --target ALL_BUILD
|
|
) else (
|
|
cmake .. -G %CMAKE_GENERATOR% -A %arch% -DORCA_TOOLS=ON %SIG_FLAG% -DBUILD_TESTS=%BUILD_TESTS% -DCMAKE_BUILD_TYPE=%build_type%
|
|
cmake --build . --config %build_type% --target ALL_BUILD -- -m
|
|
)
|
|
@echo off
|
|
cd ..
|
|
call scripts/run_gettext.bat
|
|
cd %build_dir%
|
|
cmake --build . --target install --config %build_type%
|
|
|
|
:done
|
|
@echo off
|
|
for /f "tokens=1-3 delims=:.," %%a in ("%_START_TIME: =0%") do set /a "_start_s=%%a*3600+%%b*60+%%c"
|
|
for /f "tokens=1-3 delims=:.," %%a in ("%TIME: =0%") do set /a "_end_s=%%a*3600+%%b*60+%%c"
|
|
set /a "_elapsed=_end_s - _start_s"
|
|
if %_elapsed% lss 0 set /a "_elapsed+=86400"
|
|
set /a "_hours=_elapsed / 3600"
|
|
set /a "_remainder=_elapsed - _hours * 3600"
|
|
set /a "_mins=_remainder / 60"
|
|
set /a "_secs=_remainder - _mins * 60"
|
|
echo.
|
|
echo Build completed in %_hours%h %_mins%m %_secs%s
|